Model;
      	#priors#	
      	mu ~ dflat()   
      	beta0 ~  dnorm(0.0,1.0E-6)
      	beta1  ~ dnorm(0.0, 1.0E-6)
      	beta2  ~ dnorm(0.0, 1.0E-6)
      	beta3  ~ dnorm(0.0, 1.0E-6)
      	beta4  ~ dnorm(0.0, 1.0E-6)
      	beta5  ~ dnorm(0.0, 1.0E-6)
      	eta ~ dnorm( 0.0,1.0E-6)
      	
for(k in 1: ncounts) {
      noise[k] ~ dnorm(0.0, taunoise)	
      log(lambda[k]) <- mu + rte[route[k]] + obs[obser[k]] + eta*firstyr[k] + yeareffect[year[k]] + beta0*(year[k]-fixedyear) + beta1*X1[k] + beta2*X2[k] + beta3*X3[k] + beta4*X4[k] + beta5*X1[k]*X2[k] + noise[k]		
      count[k] ~ dpois(lambda[k])
      zfcount[k] ~ dpois(lambda[k])
      err[k] <- pow(count[k]-lambda[k],2)/lambda[k]
      ferr[k] <- pow(zfcount[k]-lambda[k],2)/lambda[k]	
      eps[k] <- count[k]-lambda[k] 							
      resid[k] <- taunoise*(count[k]-lambda[k])				
      aresid[k] <- abs(count[k]-lambda[k])
          }
      gof <- sum(err[1:ncounts])
      fgof <- sum(ferr[1:ncounts])
         	diffgof <- gof-fgof
         		posdiff <- step(diffgof)
      taunoise ~ dgamma(0.001, 0.001)  	
      sdnoise <- 1/sqrt(taunoise)		
      largest <- ranked(aresid[],ncounts)
      largerthan <- step(largest-aresid[3])
         #### route effects  ######
        rte[1:nroutes] ~ car.normal(adj[], weights[], num[], taurte)
      for(j in 1:sumNumNeigh) {
            weights[j] <- 1
        }
       taurte ~ dgamma(0.5, 0.0005)
       sdrte <- 1/sqrt(taurte)
       #### observer effects  ######
       for( i in 1:nobservers) {
            obs[i] ~ dnorm(0.0, tauobs)
         }
       tauobs ~ dgamma(0.001, 0.001)
       sdobs <- 1/sqrt(tauobs)
       #### year effects  ####
       for(y in 1:nyears) {
      		yeareffect[y] ~ dnorm(0.0, tauyear)
      		yearplustrend[y] <- yeareffect[y] + beta0*(y-fixedyear)
         }
      tauyear~dgamma(0.001, 0.001)
      sdyears <- 1/sqrt(tauyear)
         #### summary statistics  ####
      for( t in 1:nyears) {
                 n[t] <- exp(beta0*(t-fixedyear)+yeareffect[t])
             }
      }